Принцип работы коннекторов в Delphi компонентах

В моих компонентах для Delphi коннектор – это объект, осуществляющий связь с внешними объектами(объектом). Внешним объектом может выступать другая программа или другое устройство, которое поддерживает тот же интерфейс или протокол связи. В процессе связи коннектор выступает клиентом. То есть задача коннектора отправить запрос и при необходимости дождаться ответа и отправить его по обратной связи (CallBack).

TKRConnector – это базовый класс всех коннекторов. Ниже представлена схема работы коннектора

Для отправки запроса используется метод Send

    procedure Send(APack: PKRBuffer; ALength: integer; ACallBack: TKRConnectorCallBack;
      AData: Pointer = nil; AWaitResult: boolean = true; ARecvLen: integer = 0;
      ADelimiter: Cardinal = 0; ADelimiterLen: integer = 0);

Задача данного метода отправить информацию о запросе в очередь на обработку. В методе Send передаются следующие параметры:

APack – указатель на буфер в котором находятся данные предназначенные для отправки. Если нужно получить ответ, то он сохранится в этот же буфер.
ALength – длинна отправляемых данных в байтах.
ACallBack – метод обратной связи типа TKRConnectorCallBack. Данный метод будет вызван после обработки запроса. Если нет необходимости в обратной связи, то можно передать nil.
AData – указатель на дополнительные данные, который будет передан в метод обратной связи (CallBack). Если есть необходимость передать дополнительную информацию о пакете, которые понадобятся в методе обратной связи, то указатель на эти данные передается в этом параметре. Если нет необходимости что-либо передавать, то устанавливаем nil.
AWaitResult – указывает на то, нужно ли ждать ответ на запрос. Если должен прийти ответ, но он не будет получен, то это будет считаться ошибкой ceNoResponse.
ARecvLen – если заранее известна длина ответа, то ее нужно указать в этом параметре. Заранее зная длину ответа коннектор будет быстрее обрабатывать входящие данные.
ADelimiter – разделитель или последовательность байт разделяющая входящие пакеты. Например в протоколе Modbus ASCII разделителем является последовательность #13#10 и для передачи этой последовательности нужно установить значение $0D0A в данный параметр. Если разделитель не используется, то устанавливаем ноль.
ADelimiterLen – длина разделителя в байтах. Если разделитель не используется, то устанавливаем ноль.

После вызова Send, информация о запросе попадает во входящую очередь коннектора, которая из себя представляет сблокированный упорядоченный список типа TKRThreadQueue. Максимальное количество запросов в очереди установлено в константе CE_QUEUE_MAX_ITEMS, а текущее количество можно узнать из свойства коннектора QueueCount. Если в момент вызова метода Send в очереди будет максимально возможное количество запросов, то будет вызван метод обратной связи с ошибкой ceQueueOverflowed.

Из входящей очереди запрос попадает в поток обработки данных типа TKRThread. Свойства коннектора WaitTime и WaitPauseTime являются настройками данного потока. Функционал потока описывается для каждого коннектора отдельно, но основные задачи во всех случаях одинаковы:

Установить соединение. Если связь не установлена, то коннектор пытается подключиться с таймаутом указанным в свойстве ConnectTimeout. Если связи нет, то коннектор будет постоянно пытаться подключиться с периодом между попытками указанным в свойстве ReconnectTime. Все запросы до установки связи будут возвращать ошибку ceNotConnection.
Отправить запрос. Отправка последовательности бай с таймаутом указанным в свойстве WriteTimeout. Если за указанный период данные отправить не удается, то возвращается ошибка ceDataNotSended.
При необходимости дождаться ответа. Если при вызове метода Send в параметре AWaitResult передано True, то будет ожидаться ответ в течении времени указанного в свойстве WaitRespTime. Общий таймаут ожидания ответа устанавливается в свойстве ReadTimeout, но промежутки по времени между частями входящего пакета не должны превышать значение свойства WaitRespTime. То есть , фактически, если в течении времени WaitRespTime ничего не будет получено, то коннектор будет считать, что ответа нет. Если в методе Send передано значение ARecvLen больше нуля, то коннектор считает, что ответ получен, если длина полученных данных больше или ровна ARecvLen и прекращает ожидание дополнительных данных. Если ответ получить не удалось, то возвращается ошибка ceNoResponse.
Результат отправить в исходящую очередь.

Исходящая очередь из себя представляет сблокированный упорядоченный список типа TKRThreadQueue. Максимальное количество запросов в очереди установлено в константе CE_QUEUE_MAX_ITEMS, а текущее количество можно узнать из свойства коннектора QueueOutCount.

Второй поток коннектора предназначен для отправки результата, то есть для вызова метода обратной связи. Свойства коннектора WaitOutTime и WaitPauseOutTime являются настройками данного потока.

Метод обратной связи представляет из себя процедуру какого либо объекта со следующими параметрами:

TKRConnectorCallBack = procedure (AError: integer; APack: PKRBuffer; ALength: integer; AData: Pointer) of Object;

AError – ошибка типа TKRConnectorError, возникшая при обработке запроса. Если в параметре придёт ноль ceOK, то значит, что в процессе обработки запроса ошибок не возникло. Текстовые представления ошибок находятся в константе CONNECTOR_ERRORS_MSG. Также текстовое представление ошибки можно получить при помощи метода коннектора ErrorMsg.
APack – указатель на тот же буфер который был передан в методе Send. В этот буфер записывается ответ, поверх запроса.
ALength – длина ответа.
AData – указатель на дополнительные данные который был передан в методе коннектора Send.

В методе обратной связи нужно учитывать то, что он напрямую вызывается из исходящего потока коннектора, то есть асинхронно основному потоку.

На данный момент есть три коннектора основанные на TKRConnector:

KRBTConnector – беспроводная связь Bluetooth
KRCOMPortConnector – связь через последовательный порт
KRTCPConnector – сетевая связь по стеку протоколов TCP/IP

Пример использования

В приведенном ниже примере через коннектор последовательного порта опрашиваются три переменные удаленного устройства по протоколу Modbus RTU. Первая переменная будет типа Word в регистре 0, вторая типа SmallInt в регистре 1 и третья типа DWORD в регистрах 2 и 3. При корректном ответе устройства значения записываются в поля TEdit, а при ошибке в эти же поля записывается текстовое представление этих ошибок. Для синхронизации метода обратной связи с основным потоком используем оконные сообщения Windows.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, KRConnector, KRCOMPortConnector, KRModbusMaster, KRModbus, KRTypes,
  StdCtrls;

const
  WM_PARAM1 = WM_USER + 1; // Сообщение о получении значения параметра 1
  WM_PARAM2 = WM_USER + 2; // Сообщение о получении значения параметра 2
  WM_PARAM3 = WM_USER + 3; // Сообщение о получении значения параметра 3
  WM_PARAM1_ERROR = WM_USER + 4; // Сообщение о ошибки при получении значения параметра 1
  WM_PARAM2_ERROR = WM_USER + 5; // Сообщение о ошибки при получении значения параметра 2
  WM_PARAM3_ERROR = WM_USER + 6; // Сообщение о ошибки при получении значения параметра 3

type
  TForm1 = class(TForm)
    KRCOMPortConnector1: TKRCOMPortConnector;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    procedure FormShow(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure WMParam1(var Msg: TMessage);message WM_PARAM1;
    procedure WMParam2(var Msg: TMessage);message WM_PARAM2;
    procedure WMParam3(var Msg: TMessage);message WM_PARAM3;
    procedure WMParamError1(var Msg: TMessage);message WM_PARAM1_ERROR;
    procedure WMParamError2(var Msg: TMessage);message WM_PARAM2_ERROR;
    procedure WMParamError3(var Msg: TMessage);message WM_PARAM3_ERROR;

    procedure UpdateParam1;
    procedure UpdateParam2;
    procedure UpdateParam3;
    procedure callBack(AError: integer; APack: PKRBuffer; ALength: integer; AData: Pointer);
  end;

var
  Form1: TForm1;
  wnd: HWND;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.callBack(AError: integer; APack: PKRBuffer; ALength: integer;
  AData: Pointer);
var
  data: PInteger;
  wd: Word;
  dw: DWORD;
  p: Pointer;
begin
  data:=AData;
  if AError=ceOK then case data^ of // Если не возникло ошибки
    1: begin
      wd:=(APack[3] shl 8) or APack[4];
      SendMessage(wnd,WM_PARAM1,NativeInt(@wd),0);
    end;
    2: begin
      wd:=(APack[3] shl 8) or APack[4];
      SendMessage(wnd,WM_PARAM2,NativeInt(@wd),0);
    end;
    3: begin
      dw:=(APack[3]shl 24)or(APack[4]shl 16)or(APack[5]shl 8)or APack[6];
      SendMessage(wnd,WM_PARAM3,NativeInt(@dw),0);
    end;
  end else case data^ of
    1: SendMessage(wnd,WM_PARAM1_ERROR,AError,0);
    2: SendMessage(wnd,WM_PARAM2_ERROR,AError,0);
    3: SendMessage(wnd,WM_PARAM3_ERROR,AError,0);
  end;
  case data^ of // Генерируем следующий запрос чтения данных
    1: UpdateParam1;
    2: UpdateParam2;
    3: UpdateParam3;
  end;
  Dispose(data);// Удаляем дополнительные данные
  Dispose(APack);// Удаляем буфер
end;

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  KRCOMPortConnector1.Active:=false;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  wnd:=Self.Handle;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  KRCOMPortConnector1.Active:=true;
  UpdateParam1;
  UpdateParam2;
  UpdateParam3;
end;

procedure TForm1.UpdateParam1; // Отправляем запрос чтения параметра 1
var
  buf: PKRBuffer;
  len, rLen: byte;
  data: PInteger;
begin
  New(buf); // Создаем буфер
  len:=MBMRTUReadHoldingRegisters( // Формируем пакет запроса
    1, // Адрес устройства
    0, // Начальный регистр
    1, // Количество регистров
    buf, // Указатель на буфер
    rLen // Получаем длину ответа на запрос
  );
  new(data); // Создаем переменную, котрую будем использовать как дополнительные данные
  data^:=1; // В переменной передаем порядковый номер параметра
  KRCOMPortConnector1.Send(
    buf, // Указатель на буфер
    len, // Длина запроса
    callBack, // Метод обратной связи
    data, // Указатель на дополнительные данные
    true, // Нужно получить ответ
    rLen // Длина ответа
  );
end;

procedure TForm1.UpdateParam2; // Отправляем запрос чтения параметра 2
var
  buf: PKRBuffer;
  len, rLen: byte;
  data: PInteger;
begin
  New(buf); // Создаем буфер
  len:=MBMRTUReadHoldingRegisters( // Формируем пакет запроса
    1, // Адрес устройства
    1, // Начальный регистр
    1, // Количество регистров
    buf, // Указатель на буфер
    rLen // Получаем длину ответа на запрос
  );
  new(data); // Создаем переменную, котрую будем использовать как дополнительные данные
  data^:=2; // В переменной передаем порядковый номер параметра
  KRCOMPortConnector1.Send(
    buf, // Указатель на буфер
    len, // Длина запроса
    callBack, // Метод обратной связи
    data, // Указатель на дополнительные данные
    true, // Нужно получить ответ
    rLen // Длина ответа
  );
end;

procedure TForm1.UpdateParam3; // Отправляем запрос чтения параметра 3
var
  buf: PKRBuffer;
  len, rLen: byte;
  data: PInteger;
begin
  New(buf); // Создаем буфер
  len:=MBMRTUReadHoldingRegisters( // Формируем пакет запроса
    1, // Адрес устройства
    2, // Начальный регистр
    2, // Количество регистров
    buf, // Указатель на буфер
    rLen // Получаем длину ответа на запрос
  );
  new(data); // Создаем переменную, котрую будем использовать как дополнительные данные
  data^:=3; // В переменной передаем порядковый номер параметра
  KRCOMPortConnector1.Send(
    buf, // Указатель на буфер
    len, // Длина запроса
    callBack, // Метод обратной связи
    data, // Указатель на дополнительные данные
    true, // Нужно получить ответ
    rLen // Длина ответа
  );
end;

procedure TForm1.WMParam1(var Msg: TMessage);
var
  p: pointer;
begin
  p:=Pointer(Msg.WParam);
  Edit1.Text:=IntToStr(Word(p^));
end;

procedure TForm1.WMParam2(var Msg: TMessage);
var
  p: pointer;
begin
  p:=Pointer(Msg.WParam);
  Edit2.Text:=IntToStr(SmallInt(p^));
end;

procedure TForm1.WMParam3(var Msg: TMessage);
var
  p: pointer;
begin
  p:=Pointer(Msg.WParam);
  Edit3.Text:=IntToStr(DWord(p^));
end;

procedure TForm1.WMParamError1(var Msg: TMessage);
begin
  Edit1.Text:=KRCOMPortConnector1.ErrorMsg(Msg.WParam);
end;

procedure TForm1.WMParamError2(var Msg: TMessage);
begin
  Edit2.Text:=KRCOMPortConnector1.ErrorMsg(Msg.WParam);
end;

procedure TForm1.WMParamError3(var Msg: TMessage);
begin
  Edit3.Text:=KRCOMPortConnector1.ErrorMsg(Msg.WParam);
end;

end.

Пример использование коннектора на основе класса TKRConnector

Вход

Комментировать

Вначале новые

Всего комментариев:

Поиск по сайту

Принцип работы коннекторов в Delphi компонентах

Пример использования

Новости сайта

Популярные статьи

Популярные загрузки